sbd-data-book

allAgNPModels.rq

Code examples: curl

SPARQL

PREFIX npo: <http://purl.bioontology.org/ontology/npo#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sbd:     <https://www.sbd4nano.eu/rdf/#>
PREFIX sbdbel:  <https://www.sbd4nano.eu/bel/#>
PREFIX dc:      <http://purl.org/dc/elements/1.1/>
PREFIX dct:     <http://purl.org/dc/terms/>
PREFIX skos:    <http://www.w3.org/2004/02/skos/core#>
SELECT ?model ?modelLabel ?provider
       (group_concat(distinct ?material_;separator=", ") AS ?material)
WHERE {
  VALUES ?superclass { npo:NPO_1892 }
  ?materialIRI rdfs:subClassOf* ?superclass ; rdfs:label ?material_ .
  ?model a sbd:Model ;
     dc:source ?providerRes.
  { ?model sbdbel:NP ?materialIRI . } UNION { ?model dct:subject / skos:narrower ?materialIRI . }
  OPTIONAL { ?model rdfs:label ?rdfsLabel }
  BIND(COALESCE(?rdfsLabel, str(?model)) AS ?modelLabel)
  ?providerRes dct:title | dc:title ?provider .
} GROUP BY ?model ?modelLabel ?provider
  ORDER BY ?model

run

Output

model	provider	material
https://h2020-sbd4nano.github.io/sbd-data-landscape/Model_20	Computational models for the assessment of manufactured nanomaterials	Ag nanoparticle, silver nanoparticle
https://h2020-sbd4nano.github.io/sbd-data-landscape/Model_21	Computational models for the assessment of manufactured nanomaterials	Ag nanoparticle, silver nanoparticle
https://h2020-sbd4nano.github.io/sbd-data-landscape/Model_28a	Computational models for the assessment of manufactured nanomaterials	Ag nanoparticle, silver nanoparticle
https://h2020-sbd4nano.github.io/sbd-data-landscape/Model_28b	Computational models for the assessment of manufactured nanomaterials	Ag nanoparticle, silver nanoparticle

Code examples

curl

curl -s https://raw.githubusercontent.com/h2020-sbd4nano/sbd-data-book/master/sparql/allAgNPModels.rq | sed 's+<lang/>+en+' > allAgNPModels.rq

curl -H "Accept: text/tab-separated-values" -G https://sbd4nanolandscape.rdf.bigcat-bioinformatics.org/sparql --data-urlencode query@allAgNPModels.rq

This SPARQL query is available under CCZero.