sbd-data-book

Silver nanoparticles

Another class of nanoforms of interest are the silver nanoparticles (npo:NPO_1892):

PREFIX npo: <http://purl.bioontology.org/ontology/npo#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
SELECT DISTINCT ?nm (SAMPLE(?nmLabel_) AS ?nmLabel)
WHERE {
  VALUES ?superclass { npo:NPO_1892 }
  ?nm rdfs:subClassOf* ?superclass ; rdfs:label ?nmLabel_ .
} GROUP BY ?nm

This gives us this list of Ag nanomaterials:

coated silver nanoparticle

citrate-coated silver nanoparticle

poly(vinylpyrrolidone)-coated Ag nanoparticle

gum arabic-coated Ag NP

Causal relationships

We can list all relationships for all carbon nanotubes:

SPARQL sparql/allAgRelationships.rq (run)

PREFIX sbd:  <https://www.sbd4nano.eu/rdf/#>
PREFIX sbdbel:  <https://www.sbd4nano.eu/bel/#>
PREFIX npo: <http://purl.bioontology.org/ontology/npo#>
PREFIX sio: <http://semanticscience.org/resource/SIO_>
PREFIX sbdbel2:  <https://h2020-sbd4nano.github.io/sbdbel/>
SELECT DISTINCT
  ?superclass (SAMPLE(?superclassLabel_) AS ?superclassLabel)
  ?nm (SAMPLE(?nmLabel_) AS ?nmLabel)
  (COUNT(DISTINCT ?relation) AS ?relations)
WHERE {
  VALUES ?ca { sbdbel:CausalAssertion sbd:CausalAssertion sbdbel2:CausalAssertion }
  VALUES ?superclass { npo:NPO_1892 }
  ?nm rdfs:subClassOf* ?superclass ; rdfs:label ?nmLabel_ .
  ?superclass rdfs:label ?superclassLabel_ .
  ?relation a ?ca ; sbdbel:NP | sio:000332 | sbdbel2:NP ?nm .
} GROUP BY ?superclass ?nm

Which gives:

AgNP datasets

All data for AgNPs can be listed with (depending on the amount of annotation):

SPARQL sparql/allAgData.rq (run)

PREFIX npo: <http://purl.bioontology.org/ontology/npo#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX sbd:     <https://www.sbd4nano.eu/rdf/#>
PREFIX sbdbel:  <https://www.sbd4nano.eu/bel/#>
PREFIX foaf:   <http://xmlns.com/foaf/0.1/> 
PREFIX rdfs:   <http://www.w3.org/2000/01/rdf-schema#> 
PREFIX erm:    <https://nanocommons.github.io/identifiers/registry#>
PREFIX enm:    <http://purl.enanomapper.org/onto/>
SELECT ?materialIRI (SAMPLE(?material_) AS ?material) ?dataset ?datasetLabel
WHERE {
  VALUES ?superclass { npo:NPO_1892 }
  VALUES ?type { sbd:Dataset sbd:Database }
  ?dataset sbdbel:NP ?materialIRI ; a ?type ; rdfs:label ?datasetLabel .
  ?materialIRI rdfs:subClassOf* ?superclass ; rdfs:label ?material_ .
} GROUP BY ?materialIRI ?dataset ?datasetLabel
  ORDER BY ?dataset

This gives:

materialIRI	material	dataset
npo:NPO_1892	Ag nanoparticle	calibrate - eNanoMapper database
npo:NPO_1892	Ag nanoparticle	nanoinformatix - eNanoMapper database
npo:NPO_1892	Ag nanoparticle	nanoreg - eNanoMapper database
npo:NPO_1892	Ag nanoparticle	nanoreg2 - eNanoMapper database
npo:NPO_1892	Ag nanoparticle	riskgone - eNanoMapper database
erm:ERM00000067	ERM00000067	riskgone - eNanoMapper database

AgNP models

All models for carbon nanotubes can be listed with:

SPARQL sparql/allAgNPModels.rq (run)

PREFIX npo: <http://purl.bioontology.org/ontology/npo#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX rdfs:    <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sbd:     <https://www.sbd4nano.eu/rdf/#>
PREFIX sbdbel:  <https://www.sbd4nano.eu/bel/#>
PREFIX dc:      <http://purl.org/dc/elements/1.1/>
PREFIX dct:     <http://purl.org/dc/terms/>
PREFIX skos:    <http://www.w3.org/2004/02/skos/core#>
SELECT ?model ?modelLabel ?provider
       (group_concat(distinct ?material_;separator=", ") AS ?material)
WHERE {
  VALUES ?superclass { npo:NPO_1892 }
  ?materialIRI rdfs:subClassOf* ?superclass ; rdfs:label ?material_ .
  ?model a sbd:Model ;
     dc:source ?providerRes.
  { ?model sbdbel:NP ?materialIRI . } UNION { ?model dct:subject / skos:narrower ?materialIRI . }
  OPTIONAL { ?model rdfs:label ?rdfsLabel }
  BIND(COALESCE(?rdfsLabel, str(?model)) AS ?modelLabel)
  ?providerRes dct:title | dc:title ?provider .
} GROUP BY ?model ?modelLabel ?provider
  ORDER BY ?model